'===========================================================================
' Subject: CD PLAYER                         Date: 10-16-99 (19:56)       
' Author:  Bearmate AnubisTech               Code: LB                     
' Origin:                                  Packet: LIBERTY.ABC
'===========================================================================
'This is the CD Player by Bearmate AnubisTech 1999
'Programmed in Liberty Basic 1.41
'CD-Access Routines by KOG Software 1999 Captain Zero


nomainwin
open "mmsystem.dll" for dll as #winmm
currentTrack=1
WindowWidth = 210
WindowHeight = 200
button #cdplayer.1, "Play", [start], UL, 5, 5, 45, 20
button #cdplayer.2, "Stop", [stop], UL, 50, 5, 45, 20
button #cdplayer.3, "<<", [backTrack], UL, 5, 30, 45, 20
button #cdplayer.4, ">>", [nextTrack], UL, 50, 30, 45, 20
button #cdplayer.5, "Eject/Close Door", [open], UL, 5, 56, 90, 20
checkbox #cdplayer.6, "SingleTrack", [set.singletrack], [reset.singletrack],5,130,100,15
graphicbox #cdplayer.g, -1, -1, 208, 200
open "CD Player v1.0" for dialog as #cdplayer
gosub [init.screen]
[loop]
input aVar$
goto [loop]


[start]
if initialize=0 then gosub [init]
if currentTrack=0 then currentTrack=1
mcicommand$="set cdaudio door closed"
opens=0
gosub [mciSub]
mcicommand$ = "open cdaudio"
gosub [mciSub]
mcicommand$ = "set cdaudio time format tmsf"
gosub [mciSub]
if currentTrack<endtrack and singleplay=1 then mcicommand$ = "play cdaudio from "+str$(currentTrack)+" to "+str$(currentTrack+1)
if singleplay=1 and currentTrack=endtrack then  mcicommand$="play cdaudio from "+str$(currentTrack)
if singleplay=0 then mcicommand$="play cdaudio from "+str$(currentTrack)
gosub [mciSub]
if r=262 then initialize=0:notice "No CD in drive or CD not ready!":goto [stop]
if r=282 then initialize=0:notice "Track Nr.:"+str$(currentTrack)+" is not available on THIS CD!"+chr$(13)+"Cd changed while playing?":goto [stop]
'cd door open r=265
if currentTrack>endtrack then
currentTrack=1
goto [start]
end if
gosub [mciSub]
goto [loop]


[stop]
mcicommand$ = "stop cdaudio"
gosub [mciSub]
mcicommand$ = "close cdaudio"
gosub [mciSub]
initialize=0
goto [loop]


[nextTrack]
if initialize=0 then goto [endfor]
if currentTrack<endtrack+1 then
currentTrack = currentTrack + 1
else
currentTrack=1
end if
currentTrack$=""
endtrack$=""
if currentTrack<10 then currentTrack$=currentTrack$+"0"
currentTrack$=currentTrack$+str$(currentTrack)
if endtrack<10 then endtrack$=endtrack$+"0"
endtrack$=endtrack$+str$(endtrack)
print #cdplayer.g,"place 0 170;color red;font arial 0 17;\Track:"+currentTrack$+" Endtrack:"+endtrack$+";flush"
[endfor]
goto [loop]


[backTrack]
if initialize=0 then goto [endback]
if currentTrack>1 then
currentTrack = currentTrack - 1
else
currentTrack=endtrack
end if
currentTrack$=""
endtrack$=""
if currentTrack<10 then currentTrack$=currentTrack$+"0"
currentTrack$=currentTrack$+str$(currentTrack)
if endtrack<10 then endtrack$=endtrack$+"0"
endtrack$=endtrack$+str$(endtrack)
print #cdplayer.g,"place 0 170;color red;font arial 0 17;\Track:"+currentTrack$+" Endtrack:"+endtrack$+";flush"
[endback]
goto [loop]


[open]
if opens=0 then
mcicommand$ = "set cdaudio door open"
opens=1
else
mcicommand$="set cdaudio door closed"
opens=0
end if
gosub [mciSub]
initialize=0
goto [loop]

[set.singletrack]
singleplay=1

goto [start]

[reset.singletrack]
singleplay=0
goto [start]

[exit]
mcicommand$ = "stop cdaudio"
gosub [mciSub]
mcicommand$ = "close cdaudio"
gosub [mciSub]
initialize=0
close #winmm
close #cdplayer
end


[mciSub]
calldll #winmm,"mciSendString", _
mcicommand$ as ptr, _
lpstrReturnString as dword, _
uReturnLength as short, _
hwndCallback as short, _
r as long
return

[init]
track=1
currentTrack$=""
endtrack$=""
currentTrack=1
initialize=1
while r<282
mcicommand$ = "open cdaudio"
gosub [mciSub]
mcicommand$ = "set cdaudio time format tmsf"
gosub [mciSub]
mcicommand$ = "play cdaudio from "+str$(track)
gosub [mciSub]
if r=262 then goto [fast]
track=track+1
wend
[fast]
if r=262 then notice"No Audio CD in drive!":initialize=0:mcicommand$="set cdaudio door closed":gosub [mciSub]:opens=0:goto [stop]
endtrack=track-2
if endtrack<0 then endtrack=1
currentTrack$=""
endtrack$=""
if currentTrack<10 then currentTrack$=currentTrack$+"0"
currentTrack$=currentTrack$+str$(currentTrack)
if endtrack<10 then endtrack$=endtrack$+"0"
endtrack$=endtrack$+str$(endtrack)
print #cdplayer.g,"place 0 170;color red;font arial 0 17;\Track:"+currentTrack$+" Endtrack:"+endtrack$+";flush"
return

[init.screen]
cls
print #cdplayer, "trapclose [exit]"
 print #cdplayer.1, "!font arial 0 14"
 print #cdplayer.2, "!font arial 0 14"
 print #cdplayer.3, "!font arial 0 14"
 print #cdplayer.4, "!font arial 0 14"
 print #cdplayer.5, "!font arial 0 14"
print #cdplayer.6,"reset"
singleplay=0
print #cdplayer.g, "font arial 0 17;fill palegray;flush;place 97 15;backcolor palegray;\CDPlayer v1.0"
print #cdplayer.g, "font arial 0 13;color blue;\This is the\CD Player \from Bearmate\AnubisTech 1999\Programmed in \Liberty Basic 1.41"
Print #cdplayer.g,"font arial 0,13;color red;\CD-Access Routines:\KOG Software 1999\   by Captain Zero\;flush"
return