'===========================================================================
' Subject: FAKE DOS, HORROR DRIVE FORMAT     Date: 09-02-97 (15:36)       
' Author:  Davey W. Taylor                   Code: QB, QBasic, PDS        
' Origin:  audio.squad@mailbox.swipnet.se  Packet: DOS.ABC
'===========================================================================
'ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ--ÄÄÄ--Ä -ù  ù
'³            ** FAKE DOS, HORROR DRIVE FORMAT **
'³                Created by Davey W Taylor
'³
'³  This program should scare the shit out of most PC users.
'³ It should be run under a 16 bit environment (WIN 3.x / DOS)
'³  in order to get the right hard drive sound / drive lights
'ÀÄÄÄÄÄ--ÄÄù-  ù   ù
' ** If you have any comments / suggestions / questions, my email is: **
' ** audio.squad@mailbox.swipnet.se                                   **

DECLARE SUB lots (t!)
LOCATE , , 1
DO
LINE INPUT "C:\>", cmd$                   'Wait for any command
LOOP UNTIL cmd$ <> ""
IF cmd$ = "NOWAY" THEN END                'NOWAY aborts
PRINT
BEEP                                      'Beep and display some screen junk
FOR n% = 1 TO 12
 PRINT CHR$(INT(RND * 200) + 50);
NEXT n%
PRINT
lots 2
PRINT "Format drive C, this will wipe out any information on that drive!!!"
PRINT "Continue? ";
DO                                        'Get Y or N
 in$ = UCASE$(INKEY$)
LOOP UNTIL in$ = "N" OR in$ = "Y"
PRINT "Y"                                 'Print Yes
PRINT
PRINT "Checking current disk format..."
lots .2
PRINT "Verifying fixed disk... "
lots 1
PRINT
PRINT "Please do not turn computer power off during the process!"
PRINT "This may cause physical damage to the disk."
s# = TIMER: DO: LOOP UNTIL TIMER - s# >= 2
PRINT
PRINT " Formating 0% done"
PRINT
PRINT
PRINT
h% = 1: c% = 1: s% = 1: n% = 0
LOCATE , , 0
DO
 n% = n% + 1
 p% = 100 / 1728 * n%

 LOCATE CSRLIN - 4, 2: PRINT "Formating"; p%; "% done"
 PRINT " Head:"; h%                       'Display format information
 PRINT " Cylinder:"; c%
 PRINT " Sector:"; s%
 s% = s% + 1
 IF n% MOD 10 = 0 THEN lots 0 ELSE WAIT &H3DA, 8
 IF s% = 13 THEN
  s% = 1: c% = c% + 1
  IF c% = 13 THEN
   c% = 1: h% = h% + 1
   IF h% = 13 THEN
    GOTO joke                             'When all are at 13, goto joke
   END IF
  END IF
 END IF
LOOP
joke:                                     'Display joke message
 LOCATE CSRLIN - 4, 2: PRINT "Formating 100 % done"
 PRINT " Head: 13"
 PRINT " Cylinder: 13"
 PRINT " Sector: 13"
 PRINT
 PRINT "Take it EASY! I was just kidding... :)"
 END

SUB lots (t!)                                   'SUB to make hard drive sound
 d# = TIMER
 DO
  OPEN "~joke.tmp" FOR OUTPUT AS #1             'open temprary file
   FOR n% = 1 TO INT(RND * 1000)
    PRINT #1, INT(RND * 256)                    'write random nuber of bytes
   NEXT n%
  CLOSE #1
  IF INT(RND * 2) + 1 = 2 THEN KILL "~joke.tmp" '50% chance to delete file
 LOOP UNTIL ABS(TIMER - d#) >= t!

 OPEN "~joke.tmp" FOR OUTPUT AS #1
 CLOSE #1
 KILL "~joke.tmp"                               'make sure the file is gone
END SUB