'===========================================================================
' Subject: PRINT BIG TEXT LETTERS            Date: 01-05-97 (19:11)       
' Author:  Denis Boyles                      Code: QB, QBasic, PDS        
' Origin:  FidoNet QUIK_BAS Echo           Packet: TEXT.ABC
'===========================================================================
'==========================================================================
'PROGRAM: BIGHIYA.BAS
' AUTHOR: Denis Boyles

'RELEASE: Public Domain (pd) Jan 5, 1997
'VERSION: 1.10

'COMPILE: Microsoft qBASIC v1.1
'     OS: MS-DOS (v6.20)

'PURPOSE: use BIOS's CGA ROM font to print out BIG text letters :)
'  NOTES: based on my assembly version, based on my C version :)
'==========================================================================

DECLARE SUB PrintBigText (text$)

CLS
PrintBigText "Hi,World!"

DEFINT A-Z
SUB PrintBigText (text$)
  DEF SEG = &HF000
  bits$ = CHR$(128) + CHR$(64) + CHR$(32) + CHR$(16) + CHR$(8) + CHR$(4) + CHR$(2) + CHR$(1)
  IF LEN(text$) > 9 THEN
    slen = 9
  ELSE
    slen = LEN(text$)
  END IF

  FOR y = 0 TO 7
    a$ = ""
    FOR ct = 1 TO slen
      byte = PEEK(&HFA6E + ASC(MID$(text$, ct, 1)) * 8 + y)
      FOR x = 1 TO 8
        IF byte AND ASC(MID$(bits$, x, 1)) THEN
          a$ = a$ + CHR$(219)
        ELSE
          a$ = a$ + CHR$(32)
        END IF
      NEXT
    NEXT
    PRINT a$
  NEXT
END SUB