'===========================================================================
' Subject: BURNING TEXT                      Date: 09-04-99 (21:32)       
' Author:  Ruud Wijtvliet                    Code: QB, QBasic, PDS        
' Origin:  wijtvliet.c@wxs.nl              Packet: GRAPHICS.ABC
'===========================================================================
'ÚÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄÄ--ÄÄÄ--Ä -
'³
'³  05-09-1999
'³  Burning Text...
'³
'³  Created by Ruud Wijtvliet
'³
'³  Feel free to use this routine in any program you want, but
'³  it would be nice if you'd send me the program you used it in.
'³  Here's the adress, although i'm 99.9% sure you won't use it ;)
'³  wijtvliet.c@wxs.nl
'³
'³  To adapt the text, go to the bottom line (the DATA statement).
'³  Just put some $trings behind the DATA (all text between "" and
'³  seperated by ,). Make sure the last word is "STOP", otherwise
'³  you'll get an errormessage (Out of DATA).
'³
'³  You could also try messing up the palette...
'³
'ÀÄÄÄÄÄÄÄÄÄÄÄ--ÄÄ -
'
'
'
'
'
SCREEN 13: CLS : RANDOMIZE TIMER

'-----------------------------------------------------------------------------

'Setting Palette:
FOR i% = 0 TO 63
 'Cold -> Warm
 colr% = i% + 1:   r% = i%:   g% = 0:    b% = 0: GOSUB Pal
 'Warm -> Hot
 colr% = i% + 63:  r% = 63:   g% = i%:   b% = 0: GOSUB Pal
NEXT i%

'-----------------------------------------------------------------------------

DO
  READ Text$
  IF Text$ = "STOP" THEN END
  Breed% = LEN(Text$) * 4 + 6
  LOCATE 12, 21 - LEN(Text$) / 2: COLOR 126: PRINT Text$
  Links% = 160 - Breed%
  Rechts% = 160 + Breed%
  Boven% = 70
  Onder% = 99

  '-----------------------------------------------------------------------------
 
  REDIM clr(Links% TO Rechts%, Boven% TO Onder%) AS INTEGER
  DIM a%(2)
  FOR x% = Links% TO Rechts%
    FOR y% = Boven% TO Onder%
      GET (x%, y%)-STEP(0, 0), a%
      clr(x%, y%) = a%(2)
    NEXT y%
  NEXT x%
 
  SLEEP
 
  '-----------------------------------------------------------------------------
  
  stap% = 0
  DO
    stap% = stap% + 1
    FOR y% = Boven% + 1 TO Onder% - 1 STEP 1
      FOR x% = Links% + 1 TO Rechts% - 1
        IF clr(x%, y% + 1) > 1 OR clr(x%, y%) > 1 THEN
          h1% = clr(x% - 1, y% - 1)
          h2% = clr(x%, y% - 1)
          h3% = clr(x% + 1, y% - 1)
          h4% = clr(x% - 1, y%)
          h5% = clr(x% + 1, y%)
          h6% = clr(x% - 1, y% + 1) * 2
          h7% = clr(x%, y% + 1) * 3
          h8% = clr(x% + 1, y% + 1) * 2
          clr(x%, y%) = (h1% + h2% + h3% + h4% + h5% + h6% + h7% + h8%) \ 12
          PSET (x%, y%), clr(x%, y%)
        END IF
      NEXT x%
    NEXT y%
  LOOP UNTIL stap% > 18
LOOP

'=============================================================================

'Palette instellen (zo = sneller dan met PALETTE):
Pal:
OUT &H3C8, colr%
OUT &H3C9, r%
OUT &H3C9, g%
OUT &H3C9, b%
RETURN

'-----------------------------------------------------------------------------

DATA "Ruud Wijtvliet Productions","Presents","Burning Text","STOP"