'===========================================================================
' Subject: SVGA LIBRARY V2.00                Date: 12-16-98 (13:23)       
' Author:  Joshua Penman                     Code: QB, PDS                
' Origin:  jpenman@hotmail.com             Packet: GRAPHICS.ABC
'===========================================================================
' кФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФП
' Г             SVGA Library for QuickBasic 4.5 version 2.00                Г
' УФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФД
' Г ў WHAT THIS IS:                                                         Г
' Г   This is a the second version of a library that I wrote for QuickBasic Г
' Г   to draw graphics on the VESA card. It's been enhanced from version    Г
' Г   1.00 in that it now supports 5 VESA modes. I have also removed page   Г
' Г   features at this stage, but will add them again when I learn how to   Г
' Г   switch video pages.                                                   Г
' Г ў DISCLAIMER:                                                           Г
' Г   Okay, here's the legal side of it. I, Joshua Penman, take 100% full   Г
' Г   credit for this code, and I retain all rights to it. I will however,  Г
' Г   allow any programmers to use this in their on code without any thanks Г
' Г   to me. Sure, a little bit of thanks in the credits would be nice, but Г
' Г   all I really would want is a couple of the program that uses this     Г
' Г   library. You are *NOT* however, allowed to distribute modified copies Г
' Г   of the library, as that wouldn't be kind to me, and you may also not  Г
' Г   use this code as a "copy/paste" thing for you're own SVGA libraries,  Г
' Г   in other words, don't copy and of this and claim it's you're own. And Г
' Г   finally, if you're moniter blows up, you're computer starts smoking,  Г
' Г   or 14 SB channels stuff up, it's you're problem, not mine. I, and     Г
' Г   Cybersoft Software will not be held responsible for anything like     Г
' Г   that, or for that matter anything else happening to you're computer,  Г
' Г   even if it can be proven that SVGALIB caused the trouble. Okay, so I  Г
' Г   don't take 100% credit, but I don't really know who wrote the screen  Г
' Г   switching routines, so I can't give them credit...                    Г
' Г ў ABOUT ME:                                                             Г
' Г   Before we actually get into explaining the code, here's a bit about   Г
' Г   me. I live in New Zealand, which, unlike many of you will no-doubt    Г
' Г   think - it's not in Sydney harbour. This is my second SVGA library &  Г
' Г   it's a lot better than my first, but I've done no speed enhancing. I  Г
' Г   will do that in the next version 2.10, which will make it heaps       Г
' Г   faster.                                                               Г
' Г ў THANKS TO:                                                            Г
' Г   I have to thank a few people for the help in this program, mainly the Г
' Г   following people: Jim Emptage for his Beizer curve routine, although  Г
' Г   I didn't actually use his code in the end, and while I said last time Г
' Г   that I'd put it sometime, I still haven't, but he still gets credit   Г
' Г   and Rich Geldreich for his Eclipse routine, because there's no easy   Г
' Г   way to do circles, but his way did it great. I'd also like to thank   Г
' Г   Andrew L Agers for his Blast! library, and really the sub on Line     Г
' Г   drawing. I didn't copy any of his code, but it made me get a move on  Г
' Г   with my own programming code.                                         Г
' Г ў HOW TO USE:                                                           Г
' Г   SVGALib requires QB.QLB and QB.BI, so load QB with QB /l, and the     Г
' Г   first line of you're program needs to be '$include: 'qb.bi', and then Г
' Г   it's really up to you. You need to call SVGASetMode, to start it up.  Г
' Г   You give different parameters to the sub to specify different modes:  Г
' Г                       &H3 - DOS text (call this before you end          Г
' Г                     &H100 - 640x400x256                                 Г
' Г                     &H101 - 640x480x256                                 Г
' Г                     &H103 - 800x600x256                                 Г
' Г                     &H105 - 1024x768x256                                Г
' Г                     &H107 - 1280x1024x256                               Г
' Г ў VERSION INFO:                                                         Г
' Г   Version 1.00      * origional version                                 Г
' Г   Version 2.00      * Added switch-banks                                Г
' Г                     * Slightly optimised line drawing                   Г
' Г ў WHERE'S SVGALIB GOING FROM HERE:                                      Г
' Г   In future, I hope to expand to 100s more VESA modes, and add more     Г
' Г   rotines to duplicate the QB routines better. I'll try to add a 16.8   Г
' Г   million colour mode too. I also hope to add heaps more SUBs like      Г
' Г   POINT and GET.                                                        Г
' Г ў CONTACTING ME:                                                        Г
' Г   While I've got heaps of E-mails addresses, use jpenman@hotmail.com,   Г
' Г   that way I know exactly what you're talking about.                    Г
' РФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФй

' ФФФФФФФФФФФФФФ
' Declare SUBs
' ФФФФФФФФФФ
	DECLARE SUB SVGABox (x1%, y1%, x2%, y2%, C%)
	DECLARE SUB SVGAFilledBox (x1%, y1%, x2%, y2%, C%)
	DECLARE SUB SVGACircle (ox!, oy!, prx!, pry!, co%)
	DECLARE SUB SVGALine (x1%, y1%, x2%, y2%, C%)
	DECLARE SUB SVGASwitchBank (NewBank%)
	DECLARE SUB SVGAPset (x%, y%, C%)
	DECLARE SUB SVGASetMode (ModeNumber%)
   
' ФФФФФФФФФФФФФФФФФФФФ
' Other stuff needed
' ФФФФФФФФФФФФФФФФ
	'$DYNAMIC
	'$INCLUDE: 'qb.bi'
	DEFINT A-Z
	DIM SHARED InRegs AS RegType
	DIM SHARED OutRegs AS RegType
	DIM SHARED Bank%
	DIM SHARED Table&(0 TO 1)
	DIM SHARED Xres AS LONG
	DIM SHARED YRes AS LONG

' ФФФФФФФФФФФФФФФФФФ
' My Demo - delete
' ФФФФФФФФФФФФФФ
   
	SVGASetMode &H101
	FOR x = 0 TO Xres - 1
		FOR y = 0 TO YRes - 1
			SVGAPset x, y, 10
			NEXT y
		NEXT x
	SVGALine 0, 0, Xres - 1, YRes - 1, 2
	SVGACircle Xres / 2 - 1, YRes / 2 - 1, Xres / 2 - 1, YRes / 2 - 1, 1
	SVGABox Xres / 2 - (Xres / 6), YRes / 2 - (YRes / 6), Xres / 2 + (Xres / 6), YRes / 2 + (YRes / 6), 4
	SVGAFilledBox Xres / 2 - (Xres / 6) + (Xres / 12), YRes / 2 - (YRes / 6) + (YRes / 12), Xres / 2 + (Xres / 6) - (Xres / 12), YRes / 2 + (YRes / 6) - (YRes / 12), 5
	a$ = INPUT$(1)
	SVGASetMode &H3

REM $STATIC
DEFSNG A-Z
' кФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФП
' Г                                SVGABox                                  Г
' УФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФД
' Г                                                                         Г
' Г Purpose:   This draws a box using the routine SVGALine from x1%, y1% to Г
' Г            x2%, y2% in colour c%                                        Г
' Г                                                                         Г
' Г Alogrithm: A simple alogrithm. Draw's four lines, the first one being   Г
' Г            The top, the second the bottom, the third the left and the   Г
' Г            fourth is the right.                                         Г
' Г                                                                         Г
' Г Input:     x1%          - Left edge                                     Г
' Г            x2%          - Right edge                                    Г
' Г            y1%          - Top edge                                      Г
' Г            y2%          - Bottom edge                                   Г
' Г            c%           - Colour of circle                              Г
' Г                                                                         Г
' Г Output:    None                                                         Г
' Г                                                                         Г
' Г Interface Assumptions: None                                             Г
' Г                                                                         Г
' Г Modification History:  version 1.00 - * initial release                 Г
' Г                                       * Removed assumptions             Г
' Г                                                                         Г
' РФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФй
SUB SVGABox (x1%, y1%, x2%, y2%, C%)
	IF x1% < 0 THEN EXIT SUB                         'off the left, then exit
	IF x2% > Xres - 1 THEN EXIT SUB                 'off the right, then exit
	IF y1% < 0 THEN EXIT SUB                          'off the top, then exit
	IF y2% > YRes - 1 THEN EXIT SUB                'off the bottom, then exit
	SVGALine x1%, y1%, x2%, y1%, C%                                 'top line
	SVGALine x1%, y2%, x2%, y2%, C%                              'bottom line
	SVGALine x1%, y1%, x1%, y2%, C%                                'left line
	SVGALine x2%, y1%, x2%, y2%, C%                               'right line
END SUB

' кФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФП
' Г                              SVGACircle                                 Г
' УФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФД
' Г                                                                         Г
' Г Purpose:   This draws a circle with it's centre at ox, oy, color co%    Г
' Г            with the X width of PRX and the Y width of PYR               Г
' Г                                                                         Г
' Г Alogrithm: A comlex alogrithm - no-one understands it... (copied from   Г
' Г            an ABC packet and modified for SVGA)                         Г
' Г                                                                         Г
' Г Input:     ox           - X center of circle                            Г
' Г            oy           - Y center of circle                            Г
' Г            prx          - X width of circle                             Г
' Г            pry          - Y width of circle                             Г
' Г            co%          - Colour of circle                              Г
' Г                                                                         Г
' Г Output:    None                                                         Г
' Г                                                                         Г
' Г Interface Assumptions: None                                             Г
' Г                                                                         Г
' Г Modification History:  version 1.00 - * initial release                 Г       
' Г                        version 2.00 - * removed assumptions             Г
' Г                                       * fixed problem with lines        Г
' Г                                                                         Г
' РФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФй
SUB SVGACircle (ox, oy, prx, pry, co%)
	DIM xe AS LONG, ye AS LONG, e AS LONG
	IF pry = 0 THEN
		SVGALine (ox - prx), (oy), (ox + prx), (oy), co%
		EXIT SUB
		END IF
	IF prx = 0 THEN
		SVGALine (ox), (oy - pry), (ox), (oy + pry), co%
		EXIT SUB
		END IF
	IF pry <= prx THEN
		x = 0: y = pry
		xe = 0: ye = CLNG(prx) * prx
		e = -ye \ 2: C = ye \ pry
		DO
			IF e <= 0 THEN
			DO
				SVGAPset (ox + x), (oy + y), co%: SVGAPset (ox - x), (oy + y), co%
				SVGAPset (ox + x), (oy - y), co%: SVGAPset (ox - x), (oy - y), co%
				x = x + 1
				xe = xe + pry
				e = e + xe
				LOOP WHILE e <= 0
			ELSE
				SVGAPset (ox + x), (oy + y), co%: SVGAPset (ox - x), (oy + y), co%
				SVGAPset (ox + x), (oy - y), co%: SVGAPset (ox - x), (oy - y), co%
				END IF
			y = y - 1
			ye = ye - C
			e = e - ye
			LOOP UNTIL y = 0
		SVGAPset (ox + x), (oy), co%: SVGAPset (ox - x), (oy), co%
		SVGAPset (ox + x), (oy), co%: SVGAPset (ox - x), (oy), co%
	ELSE
		x = 0: y = prx
		xe = 0: ye = CLNG(pry) * pry
		e = -ye \ 2: C = ye \ prx
		DO
			IF e <= 0 THEN
			DO
				SVGAPset (ox + y), (oy + x), co%: SVGAPset (ox - y), (oy + x), co%
				SVGAPset (ox + y), (oy - x), co%: SVGAPset (ox - y), (oy - x), co%
				x = x + 1
				xe = xe + prx
				e = e + xe
				LOOP WHILE e <= 0
			ELSE
				SVGAPset (ox + y), (oy + x), co%: SVGAPset (ox - y), (oy + x), co%
				SVGAPset (ox + y), (oy - x), co%: SVGAPset (ox - y), (oy - x), co%
				END IF
			y = y - 1
			ye = ye - C
			e = e - ye
			LOOP UNTIL y = 0
		SVGAPset (ox), (oy + x), co%: SVGAPset (ox), (oy + x), co%
		SVGAPset (ox), (oy - x), co%: SVGAPset (ox), (oy - x), co%
		END IF
END SUB

DEFINT A-Z
' кФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФП
' Г                             SVGAFilledBox                               Г
' УФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФД
' Г                                                                         Г
' Г Purpose:   This draws a box using the routine SVGALine from x1%, y1% to Г
' Г            x2%, y2% in colour c%                                        Г
' Г                                                                         Г
' Г Alogrithm: A simple alogrithm.                                          Г
' Г                                                                         Г
' Г Input:     x1%          - Left edge                                     Г
' Г            x2%          - Right edge                                    Г
' Г            y1%          - Top edge                                      Г
' Г            y2%          - Bottom edge                                   Г
' Г            c%           - Colour of circle                              Г
' Г                                                                         Г
' Г Output:    None                                                         Г
' Г                                                                         Г
' Г Interface Assumptions: None                                             Г
' Г                                                                         Г
' Г Modification History:  version 1.00 - * initial release                 Г      
' Г                        version 2.00 - * removed assumptions             Г
' Г                                                                         Г
' РФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФй
SUB SVGAFilledBox (x1%, y1%, x2%, y2%, C%)
	IF x1% < 0 THEN EXIT SUB                         'off the left, then exit
	IF x2% > Xres - 1 THEN EXIT SUB                 'off the right, then exit
	IF y1% < 0 THEN EXIT SUB                          'off the top, then exit
	IF y2% > YRes - 1 THEN EXIT SUB                'off the bottom, then exit
	FOR y% = y1% TO y2%                                           'start loop
		SVGALine x1%, y%, x2%, y%, C%                          'draw the line
		NEXT y%                                                      'loop...
END SUB

DEFSNG A-Z
' кФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФП
' Г                                SVGALine                                 Г
' УФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФД
' Г                                                                         Г
' Г Purpose:   Draws a line in SVGA from x1%, y1% to x2%, y2% in colour c%  Г
' Г                                                                         Г
' Г Alogrithm: This alogrithm has changed quite a lot since version 1.00,   Г
' Г            in that it can now be up to 500% faster (only on lines that  Г
' Г            were 2 pixels big). I'm using Pythagora's Therom to calcula- Г
' Г            te the number of pixels to be drawn, and I'm only drawing    Г
' Г            that many, unlike version 1.00 which drew 1000 no matter how Г
' Г            long it was.                                                 Г
' Г                                                                         Г
' Г Input:     x1%          - Left edge                                     Г
' Г            x2%          - Right edge                                    Г
' Г            y1%          - Top edge                                      Г
' Г            y2%          - Bottom edge                                   Г
' Г            c%           - Colour of line                                Г
' Г                                                                         Г
' Г Output:    None                                                         Г
' Г                                                                         Г
' Г Interface Assumptions: None                                             Г
' Г                                                                         Г
' Г Modification History:  version 1.00 - * initial release                 Г
' Г                        version 2.00 - * Put in an alogrythim            Г
' Г                                       * removed assumptions             Г
' Г                                                                         Г
' РФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФй
SUB SVGALine (x1%, y1%, x2%, y2%, C%)
	IF x2% < x1% THEN SWAP x1%, x2%             'switch if varibles are wrong
	IF y2% < y1% THEN SWAP y1%, y2%             'switch if varibles are wrong
	IF x1% < 0 THEN x1% = 0                                  'if off the left
	IF x2% > Xres - 1 THEN x2% = Xres - 1                   'if off the right
	IF y1% < 0 THEN y1% = 0                                   'if off the top
	IF y2% > YRes - 1 THEN y2% = YRes - 1                  'if off the bottom
	IF C% < 0 THEN EXIT SUB                        'invalid colour, then exit
	WHILE C% > 255                                    'loop until c% is valid
		C% = C% - 255                                           'subtract 255
		WEND                                                            'loop
	TotalMoveSqrd = ((x2% - x1%) ^ 2) + ((y2% - y1%) ^ 2)'calculate the total
	TotalMove = SQR(TotalMoveSqrd) 'number of pixels in the line (Pythagoras)
	XStep = (x2% - x1%) / TotalMove                'calculate x move per step
	YStep = (y2% - y1%) / TotalMove                'calculate y move per step
	StartX = x1%                                  'set for later calculations
	StartY = y1%                                  'set for later calculations
	FOR i = 1 TO TotalMove                                    'start the loop
		SVGAPset StartX + (XStep * (i - 1)), StartY + (YStep * (i - 1)), C%
		NEXT i                   ' <<< loop           ^^^ Pset at right place
END SUB

' кФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФП
' Г                                SVGAPset                                 Г
' УФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФД
' Г                                                                         Г
' Г Purpose:   Draws a dot at location x%, y%, in colour c%                 Г
' Г                                                                         Г
' Г Alogrithm: None.                                                        Г
' Г                                                                         Г
' Г Input:     x%           - Pixel X co-ord                                Г
' Г            x%           - Pixel Y co-ord                                Г
' Г            c%           - Colour of pixel                               Г
' Г                                                                         Г
' Г Output:    None                                                         Г
' Г                                                                         Г
' Г Interface Assumptions: None                                             Г
' Г                                                                         Г
' Г Modification History:  version 1.00 - * initial release                 Г
' Г                        version 2.00 - * Added "lookup" table            Г
' Г                                       * Added Switch banks              Г
' Г                                       * Removed all assumptions         Г
' Г                                                                         Г
' РФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФй
SUB SVGAPset (x%, y%, C%)
	IF x% < 0 THEN EXIT SUB                          'off the left, then exit
	IF y% < 0 THEN EXIT SUB                           'off the top, then exit
	IF x% > Xres - 1 THEN EXIT SUB                  'off the right, then exit
	IF y% > YRes - 1 THEN EXIT SUB                 'off the bottom, then exit
	IF C% < 0 THEN EXIT SUB                        'invalid colour, then exit
	WHILE C% > 255                                    'loop until c% is valid
		C% = C% - 255                                           'subtract 255
		WEND                                                            'loop
	DEF SEG = &HA000                                       'set video segment
	NewBank% = (Table&(y%) + x%) \ 65536                      'calculate bank
	IF NewBank% <> Bank% THEN SVGASwitchBank NewBank%             'Switchbank
	POKE (Table&(y%) + x% + 1) MOD 65536, C%                     'Actual PSET
END SUB

' кФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФП
' Г                              SVGASetMode                                Г
' УФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФД
' Г                                                                         Г
' Г Purpose:   Sets screen to and compatible mode                           Г
' Г                                                                         Г
' Г Alogrithm: None                                                         Г
' Г                                                                         Г
' Г Input:     ModeNumber% - &H100 (640x400x256)                            Г
' Г                          &H101 (640x480x256)                            Г
' Г                          &H103 (800x600x256)                            Г
' Г                          &H105 (1024x768x256)                           Г
' Г                          &H107 (1280x1024x256)                          Г
' Г                          &H3 (Standard DOS text)                        Г
' Г                                                                         Г
' Г Output:    None                                                         Г
' Г                                                                         Г
' Г Interface Assumptions: Mode number one of the above                     Г
' Г                                                                         Г
' Г Modification History:  version 1.00 - * Initial release                 Г
' Г                        version 2.00 - * Added different mode numbers    Г
' Г                                       * Added a "look-up" table         Г
' Г                                       * Added "switch-bank" support     Г
' Г                                       * Added XRes and YRes for errors  Г
' Г                                       * Added a standard mode return    Г
' Г                                                                         Г
' РФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФй
SUB SVGASetMode (ModeNumber%)
	InRegs.ax = &H4F02                                   'Set function number
	InRegs.bx = ModeNumber%                                      'Set varible
	INTERRUPT &H10, InRegs, OutRegs                           'Call Interrupt
	IF ModeNumber% = &H3 THEN EXIT SUB                'If Text, then quit now
	IF ModeNumber% = &H100 THEN Xres = 640: YRes = 400             'case mode
	IF ModeNumber% = &H101 THEN Xres = 640: YRes = 480             'case mode
	IF ModeNumber% = &H103 THEN Xres = 800: YRes = 600             'case mode
	IF ModeNumber% = &H105 THEN Xres = 1024: YRes = 768            'case mode
	IF ModeNumber% = &H107 THEN Xres = 1280: YRes = 1024           'case mode
	IF Xres = 0 THEN Xres = 1: YRes = 1     'stops error if non-standard mode
	REDIM Table&(0 TO YRes - 1)                      're-setup's Lookup table
	FOR x% = 0 TO YRes - 1                                   'Start make loop
		Table&(x%) = x% * Xres - 1                             'Stick in info
	NEXT x%                                                          'Loop...
END SUB

' кФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФП
' Г                              SVGASwitchBank                             Г
' УФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФД
' Г                                                                         Г
' Г Purpose:   Switches the bank                                            Г
' Г                                                                         Г
' Г Alogrithm: None                                                         Г
' Г                                                                         Г
' Г Input:     NewBank%                                                     Г
' Г                                                                         Г
' Г Output:    None                                                         Г
' Г                                                                         Г
' Г Interface Assumptions: Valid NewBank%                                   Г
' Г                                                                         Г
' Г Modification History:  version 2.00 - * Initial release                 Г
' Г                                                                         Г
' РФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФФй
SUB SVGASwitchBank (NewBank%)
	InRegs.ax = &H4F05                                   'set function number
	InRegs.bx = 0                                                   'set to 0
	InRegs.dx = NewBank%                                     'set to new bank
	INTERRUPT &H10, InRegs, OutRegs                           'call interrupt
	Bank% = NewBank%                                     'update bank varible
END SUB