'===========================================================================
' Subject: COLOR MORPH                       Date: 09-06-96 (12:31)       
' Author:  Ryan White                        Code: QB, QBasic, PDS        
' Origin:  BIGFOOT@SunBelt.Net             Packet: GRAPHICS.ABC
'===========================================================================
'color morph
'By Ryan White
'This is a sample of my abilities with palettes and wierd designs.
'If you would like to get more of these type programs, write me at
'Bigfoot@Sunbelt.Net  or  Bigfoot@InfoAve.Net
'I have more than 575 Qbasic programs to my name, and it grows daily.
'Ah well, enjoy...

SCREEN 13
CLS
DEFINT A-Z
DIM c(255, 2), co(255, 2)
FOR n = 0 TO 15
'black white red orange yellow green blue's purple ~then backwards~
'0-15      black   to  white
c(n, 0) = n * 4: c(n, 1) = n * 4: c(n, 2) = n * 4
'16-31     white   to  red
c(n + 16, 0) = 63: c(n + 16, 1) = 63 - n * 4: c(n + 16, 2) = 63 - n * 4
'32-47     red     to  orange
c(n + 32, 0) = 63: c(n + 32, 1) = n * 2: c(n + 32, 2) = 0
'48-63     orange  to  yellow
c(n + 48, 0) = 63: c(n + 48, 1) = n * 2 + 31: c(n + 48, 2) = 0
'64-79     yellow  to  green
c(n + 64, 0) = 63 - n * 4: c(n + 64, 1) = 63: c(n + 64, 2) = 0
'80-95     green   to  l.blue
c(n + 80, 0) = 0: c(n + 80, 1) = 63 - n * 2: c(n + 80, 2) = n * 4
'96-111    l.blue  to  d.blue
c(n + 96, 0) = 0: c(n + 96, 1) = 32 - n * 2: c(n + 96, 2) = 60
'112-127   d.blue  to  purple
c(n + 112, 0) = n * 3: c(n + 112, 1) = 0: c(n + 112, 2) = 60
'128-143   purple  to  d.blue
c(n + 128, 0) = 45 - n * 3: c(n + 128, 1) = 0: c(n + 128, 2) = 60
'144-159   d.blue  to  l.blue
c(n + 144, 0) = 0: c(n + 144, 1) = n * 2: c(n + 144, 2) = 60
'160-175   l.blue  to  green
c(n + 160, 0) = 0: c(n + 160, 1) = 30 + n * 2: c(n + 160, 2) = 60 - n * 4
'176-191   green   to  yellow
c(n + 176, 0) = n * 4: c(n + 176, 1) = 63: c(n + 176, 2) = 0
'192-207   yellow  to  orange
c(n + 192, 0) = 63: c(n + 192, 1) = 60 - n * 2: c(n + 192, 2) = 0
'208-223   orange  to  red
c(n + 208, 0) = 63: c(n + 208, 1) = 30 - n * 2: c(n + 208, 2) = 0
'224-239   red     to  gray
c(n + 224, 0) = 60 - n * 2: c(n + 224, 1) = n * 2: c(n + 224, 2) = n * 2
'240-255   gray    to  black
c(n + 240, 0) = 30 - n * 2: c(n + 240, 1) = 30 - n * 2: c(n + 240, 2) = 30 - n * 2
NEXT n
FOR n = 1 TO 255: OUT &H3C8, n: FOR m = 0 TO 2: OUT &H3C9, c(n, m): NEXT m: NEXT n

FOR x = 0 TO 319
c = c + 1: IF c = 256 THEN c = 1
LINE (x, 0)-(159, 100), c
NEXT x
FOR y = 0 TO 199
c = c + 1: IF c = 256 THEN c = 1
LINE (319, y)-(159, 100), c
NEXT y
FOR x = 319 TO 0 STEP -1
c = c + 1: IF c = 256 THEN c = 1
LINE (x, 199)-(159, 100), c
NEXT x
FOR y = 199 TO 0 STEP -1
c = c + 1: IF c = 256 THEN c = 1
LINE (0, y)-(159, 100), c
NEXT y

FOR r = 60 TO 1 STEP -1
FOR m = -1 TO 1
c = c + 1: IF c = 256 THEN c = 1
CIRCLE (159, 100 + m), r, c, , , 1
NEXT m
NEXT r

DO UNTIL INKEY$ <> ""
FOR n = 1 TO 255: OUT &H3C7, n: FOR m = 0 TO 2: co(n, m) = INP(&H3C9): NEXT m: NEXT n
c(255, 0) = co(1, 0): c(255, 1) = co(1, 1): c(255, 2) = co(1, 2)
FOR n = 1 TO 254: FOR m = 0 TO 2: c(n, m) = co(n + 1, m): NEXT m: NEXT n
FOR n = 1 TO 255: OUT &H3C8, n: FOR m = 0 TO 2: OUT &H3C9, c(n, m): NEXT m: NEXT n
LOOP